427

I need to know where JDK is located on my machine.

On running Java -version in cmd, it shows the version as '1.6.xx'. To find the location of this SDK on my machine I tried using echo %JAVA_HOME% but it is only showing 'JAVA_HOME' (as there is no 'JAVA_PATH' var set in my environment variables).

alternatively, you can search in the windows search , on top left corner with the keyword "jdk" and in the search results you can identify the folder based on the version number [in case you have multiple JDK installed]

Improve this question
3
  • 2
    unfortunately, I think some of the answers below may not work because apparently something changed with more recent versions of Java. Today I downloaded the version 7.60 Java SDK. After some searching, found it at C:\Program Files (x86)\Java\jdk1.7.0_60. There was an older version 6 JRE already installed. It was at C:\Program Files\Java and this was on the %PATH% not the newer install. Commented Jun 10, 2014 at 16:41
  • 2
    The best answer is at the bottom, a one-liner from majkinetor for PowerShell: $p='HKLM:\SOFTWARE\JavaSoft\Java Development Kit'; $v=(gp $p).CurrentVersion; (gp $p/$v).JavaHome Commented Mar 14, 2018 at 22:51
  • 1
    one more thing, if your jdk was bundled with intellij idea, it could be somewhere near the idea installation. For me it was in a folder 1 directory up from the idea folder, and the PATH variable pointed to a jre in Program Files Commented Oct 16, 2018 at 18:38

26 Answers 26

Reset to default
491

If you are using Linux/Unix/Mac OS X:

Try this:

$ which java

Should output the exact location.

After that, you can set JAVA_HOME environment variable yourself.

In my computer (Mac OS X - Snow Leopard):

$ which java
/usr/bin/java
$ ls -l /usr/bin/java
lrwxr-xr-x  1 root  wheel  74 Nov  7 07:59 /usr/bin/java -> /System/Library/Frameworks/JavaVM.framework/Versions/Current/Commands/java

If you are using Windows:

c:\> for %i in (java.exe) do @echo.   %~$PATH:i
Improve this answer
Sign up to request clarification or add additional context in comments.

Actually, the form %VAR_NAME% is Windows
Updated the answer with Linux/Unix/Mac OS X and Windows examples.
where java works in Windows (at least as of Windows 7) But if you really want a JDK and not a JRE you need to look in the returned directories for 'bin/javac/
where java doesn't give the full path if java.exe is on the Path, whereas Pablo's for... solution does so is preferable.
MacOS one-liner: ls -l $(which java) | awk '{print $11}'
169

Windows > Start > cmd > 

C:> for %i in (javac.exe) do @echo.   %~$PATH:i

If you have a JDK installed, the Path is displayed,
for example: C:\Program Files\Java\jdk1.6.0_30\bin\javac.exe

Improve this answer

Windows(7+) => where javac.exe
In windows it is, where java
where java works only if the executable is in the PATH. If for whatever reason, javac is not in the path, it won't return any result, but it doesn't mean JDK is not installed. So in general case, the file search solution proposed by @grokster solution will guarantee a result (thought might take time to complete).
The 'for-loop' stuff did not work, however, I found it here: C:\Program Files (x86)\Java\jdk1.6.0_24\bin>
Notice that if you are following this (codelabs.developers.google.com/codelabs/…) tutorial to use android studio, the actual path would not be what is returned by the command above. Most likely, you would have something like "C:\\Program Files\Java|<jdk>" where instead of "jdk" you would have something like "jdk-10.0.1" for JDK version 10.
145

In Windows at the command prompt

where javac

Improve this answer

In windows it is, where java
Note, this only works if javac is in the PATH. If it's not, this command will say that it's not found, but JDK could still be installed. Use other methods if you PATH hasn't been updated after JDK installation.
what other methods? You mentioned using for %i in (javac.exe) do @echo. %~$PATH:i, but as you wrote, it won't work if you didn't set it in the PATH.
what if i have mutliple JDKs ?
"where java" and "where javac" return nothing using the Windows 10 machine I am currently on.
57

Command line:

Run where java on Command Prompt.

enter image description here

GUI:

On Windows 10 you can find out the path by going to Control Panel > Programs > Java. In the panel that shows up, you can find the path as demonstrated in the screenshot below. In the Java Control Panel, go to the 'Java' tab and then click the 'View' button under the description 'View and manage Java Runtime versions and settings for Java applications and applets.'

This should work on Windows 7 and possibly other recent versions of Windows.

enter image description here

Improve this answer

I'm on windows 10 and there's no java in control panel
Are you sure Java is installed and it was installed using the windows installation package?
You can try looking at your account and system environment variables to find out where java might be installed, look for javacpl.exe
This approach doesn't actually seem to show the JDK location. See stackoverflow.com/a/72278455/3368818.
34

In windows the default is: C:\Program Files\Java\jdk1.6.0_14 (where the numbers may differ, as they're the version).

Improve this answer

how would you retrieve the differing version number?
just navigate to the location incrementally from your explorer, and you'll see the jdk folder version that you installed.
Sometimes the JDK is distributed from 3rd parties, in which case you may not have Java under Program FIles, @Pablo answer helped locate perfectly
28

Plain and simple on Windows platforms:

where java

Improve this answer

It results in wrong Java location C:\WINDOWS\System32\java.exe. But the actual jdk is installed at C:\Java\jdk1.7.0\ (as JAVA_HOME is set)
27

Java installer puts several files into %WinDir%\System32 folder (java.exe, javaws.exe and some others). When you type java.exe in command line or create process without full path, Windows runs these as last resort if they are missing in %PATH% folders.

You can lookup all versions of Java installed in registry. Take a look at HKLM\SOFTWARE\JavaSoft\Java Runtime Environment and HKLM\SOFTWARE\Wow6432Node\JavaSoft\Java Runtime Environment for 32-bit java on 64 bit Windows.

This is how java itself finds out different versions installed. And this is why both 32-bit and 64-bit version can co-exist and works fine without interfering.

Improve this answer

Comments

26

Under Windows, you can use

C:>dir /b /s java.exe

to print the full path of each and every "java.exe" on your C: drive, regardless of whether they are on your PATH environment variable.

Improve this answer

that didn't work for me
21

In Windows PowerShell you can use the Get-Command function to see where Java is installed:

Get-Command -All java

Or

gcm -All java

The -All part makes sure to show all places it appears in the Path lookup. Below is example output.

PS C:> gcm -All java

CommandType     Name                                               Version    Source
-----------     ----                                               -------    ------
Application     java.exe                                           8.0.202.8  C:\Program Files (x86)\Common Files\Oracle\Java\jav...
Application     java.exe                                           8.0.131... C:\ProgramData\Oracle\Java\javapath\java.exe
Improve this answer

Comments

19

The batch script below will print out the existing default JRE. It can be easily modified to find the JDK version installed by replacing the Java Runtime Environment with Java Development Kit.

@echo off

setlocal

::- Get the Java Version
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment"
set VALUE=CurrentVersion
reg query %KEY% /v %VALUE% 2>nul || (
    echo JRE not installed 
    exit /b 1
)
set JRE_VERSION=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JRE_VERSION=%%b
)

echo JRE VERSION: %JRE_VERSION%

::- Get the JavaHome
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set VALUE=JavaHome
reg query %KEY% /v %VALUE% 2>nul || (
    echo JavaHome not installed
    exit /b 1
)

set JAVAHOME=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JAVAHOME=%%b
)

echo JavaHome: %JAVAHOME%

endlocal
Improve this answer

Comments

15

In a Windows command prompt, just type:

set java_home

Or, if you don't like the command environment, you can check it from:

Start menu > Computer > System Properties > Advanced System Properties. Then open Advanced tab > Environment Variables and in system variable try to find JAVA_HOME.

enter image description here

Improve this answer

This gives me the jdk folder. When I run System.getProperty("java.home") in a Scala Worksheet, it gives me the jre subfolder. There's apparently some ambiguity about Java Home.
13

Powershell one liner:

$p='HKLM:\SOFTWARE\JavaSoft\Java Development Kit'; $v=(gp $p).CurrentVersion; (gp $p/$v).JavaHome
Improve this answer

For JDK 11 use $p='HKLM:\SOFTWARE\JavaSoft\JDK'; $v=(gp $p).CurrentVersion; (gp $p/$v).JavaHome
11

Run this program from commandline:

// File: Main.java
public class Main {

    public static void main(String[] args) {
       System.out.println(System.getProperty("java.home"));
    }

}


$ javac Main.java
$ java Main
Improve this answer

wouldn't she have to compile this first?
That will find a JRE if it is installed and on the path first.
10

More on Windows... variable java.home is not always the same location as the binary that is run.

As Denis The Menace says, the installer puts Java files into Program Files, but also java.exe into System32. With nothing Java related on the path java -version can still work. However when PeterMmm's program is run it reports the value of Program Files as java.home, this is not wrong (Java is installed there) but the actual binary being run is located in System32.

One way to hunt down the location of the java.exe binary, add the following line to PeterMmm's code to keep the program running a while longer:

try{Thread.sleep(60000);}catch(Exception e) {}

Compile and run it, then hunt down the location of the java.exe image. E.g. in Windows 7 open the task manager, find the java.exe entry, right click and select 'open file location', this opens the exact location of the Java binary. In this case it would be System32.

Improve this answer

Comments

9

Have you tried looking at your %PATH% variable. That's what Windows uses to find any executable.

Improve this answer

Yep. Echo %PATH%. Mine seems to be in c:\Program Files\Java on Windows 7
6

Just execute the set command in your command line. Then you see all the environments variables you have set.

Or if on Unix you can simplify it:

$ set | grep "JAVA_HOME"
Improve this answer

Thanks Roflcoptr, it was indeed useful to learn about 'set'. In my system its is showing two entries for same variable, how can I delete the incorrect one.
5

On macOS, run:

cd /tmp && echo 'public class Main {public static void main(String[] args) {System.out.println(System.getProperty("java.home"));}}' > Main.java && javac Main.java && java Main

On my machine, this prints:

/Library/Java/JavaVirtualMachines/jdk-9.0.4.jdk/Contents/Home

Note that running which java does not show the JDK location, because the java command is instead part of JavaVM.framework, which wraps the real JDK:

$ which java
/usr/bin/java
/private/tmp
$ ls -l /usr/bin/java
lrwxr-xr-x  1 root  wheel  74 14 Nov 17:37 /usr/bin/java -> /System/Library/Frameworks/JavaVM.framework/Versions/Current/Commands/java
Improve this answer

Comments

4

This is OS specific. On Unix:

which java

will display the path to the executable. I don't know of a Windows equivalent, but there you typically have the bin folder of the JDK installation in the system PATH:

echo %PATH%
Improve this answer

I was gonna give that answer, too, but he's clearly looking for a windows answer.
@DonBranson He changed the text to include Windows after this post submitted.
3

May 2024
The easiest and most accurate way is to search java.exe itself :

dir /b /s java.exe
  • Run above command in the root folder, In my case ( C:\ ) :

enter image description here

Improve this answer

This is working only in Command Line (cmd.exe) not in Windows Powershell
2

None of these answers are correct for Linux if you are looking for the home that includes the subdirs such as: bin, docs, include, jre, lib, etc.

On Ubuntu for openjdk1.8.0, this is in: /usr/lib/jvm/java-1.8.0-openjdk-amd64

and you may prefer to use that for JAVA_HOME since you will be able to find headers if you build JNI source files. While it's true which java will provide the binary path, it is not the true JDK home.

Improve this answer

Comments

1

I have improved munsingh's answer above by testing for the registry key in 64-bit and 32-bit registries, if needed:

::- Test for the registry location  
SET VALUE=CurrentVersion
SET KEY_1="HKLM\SOFTWARE\JavaSoft\Java Development Kit"
SET KEY_2=HKLM\SOFTWARE\JavaSoft\JDK
SET REG_1=reg.exe
SET REG_2="C:\Windows\sysnative\reg.exe"
SET REG_3="C:\Windows\syswow64\reg.exe"

SET KEY=%KEY_1%
SET REG=%REG_1%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_1%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

::- %REG_2% is for 64-bit installations, using "C:\Windows\sysnative"
SET KEY=%KEY_1%
SET REG=%REG_2%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_2%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

::- %REG_3% is for 32-bit installations on a 64-bit system, using "C:\Windows\syswow64"
SET KEY=%KEY_1%
SET REG=%REG_3%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

SET KEY=%KEY_2%
SET REG=%REG_3%
%REG% QUERY %KEY% /v %VALUE% 2>nul
IF %ERRORLEVEL% EQU 0 GOTO _set_value

:_set_value
FOR /F "tokens=2,*" %%a IN ('%REG% QUERY %KEY% /v %VALUE%') DO (
    SET JDK_VERSION=%%b
)
SET KEY=%KEY%\%JDK_VERSION%
SET VALUE=JavaHome
FOR /F "tokens=2,*" %%a IN ('%REG% QUERY %KEY% /v %VALUE%') DO (
    SET JAVAHOME=%%b
)
ECHO "%JAVAHOME%"
::- SETX JAVA_HOME "%JAVAHOME%"

reference for access to the 64-bit registry

Improve this answer

Comments

1

Maybe the above methods work... I tried some and didn't for me. What did was this :

Run this in terminal :

/usr/libexec/java_home
Improve this answer

Comments

1

Simple method (Windows): Open an application using java. press ctrl + shift + esc

Right click on OpenJDK platform binary. Click open file location. Then it will show java/javaw.exe then go to the top where it shows the folder and click on the jdk then right copy the path, boom. (Wont work for apps using bundled jre paths/runtimes, because it will show path to the bundled runtime)

Improve this answer

Comments

0

in Windows cmd:

set "JAVA_HOME"
Improve this answer

Comments

0 
#!/bin/bash

if [[ $(which ${JAVA_HOME}/bin/java) ]]; then
    exe="${JAVA_HOME}/bin/java"
elif [[ $(which java) ]]; then
    exe="java"
else 
    echo "Java environment is not detected."
    exit 1
fi

${exe} -version

For windows:

@echo off
if "%JAVA_HOME%" == "" goto nojavahome

echo Using JAVA_HOME            :   %JAVA_HOME%

"%JAVA_HOME%/bin/java.exe" -version
goto exit

:nojavahome
echo The JAVA_HOME environment variable is not defined correctly
echo This environment variable is needed to run this program.
goto exit

:exit

This link might help to explain how to find java executable from bash: http://srcode.org/2014/05/07/detect-java-executable/

Improve this answer

While this link may answer the question, it is better to include the essential parts of the answer here and provide the link for reference. Link-only answers can become invalid if the linked page changes.
Thanks @ShaifulIslam, your point is right. I added the code from the link.
0

Script for 32/64 bit Windows.

@echo off

setlocal enabledelayedexpansion

::- Get the Java Version
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment"
set KEY64="HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment"
set VALUE=CurrentVersion
reg query %KEY% /v %VALUE% 2>nul || (
    set KEY=!KEY64!
    reg query !KEY! /v %VALUE% 2>nul || (
    echo JRE not installed 
    exit /b 1
)
)

set JRE_VERSION=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JRE_VERSION=%%b
)

echo JRE VERSION: %JRE_VERSION%

::- Get the JavaHome
set KEY="HKLM\SOFTWARE\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set KEY64="HKLM\SOFTWARE\WOW6432Node\JavaSoft\Java Runtime Environment\%JRE_VERSION%"
set VALUE=JavaHome
reg query %KEY% /v %VALUE% 2>nul || (
    set KEY=!KEY64!
    reg query !KEY! /v %VALUE% 2>nul || (
    echo JavaHome not installed
    exit /b 1
)
)

set JAVAHOME=
for /f "tokens=2,*" %%a in ('reg query %KEY% /v %VALUE% ^| findstr %VALUE%') do (
    set JAVAHOME=%%b
)

echo JavaHome: %JAVAHOME%

endlocal
Improve this answer

Comments

Start asking to get answers

Find the answer to your question by asking.

Ask question

Explore related questions

See similar questions with these tags.