Tcl异常处理命令之try、throw

try

try body ?handler...? ?finally script?

 Tcl8.6新增，此命令执行脚本body，并根据脚本的结果(正常退出、错误或其他异常结果)运行处理程序脚本handler来处理。如果存在finally，那么无论是否发生错误最后都会执行finally分支中的脚本script。handler可以是以下两种形式：

on

on code variableList script

如果body执行结果为异常代码code，则用on匹配。code可以是整数或者是字符ok、error、return、break或continue，分别对应整数0-4。

 trap

trap pattern variableList script

 如果body执行产生错误，并且解释器状态字典中的-errorcode的前缀与pattern相同，则用trap匹配。从-errorcode中提取的前缀单词的数量等于pattern列表的长度。在比较之前-errorcode和pattern字间的空格会进行规范化。

variableList是变量列表。如果列表第一个元素非空，那么它的值将会是try中body执行的结果，包含人类可读形式的任何错误。如果第二个元素非空，那么它的值会是body执行结束时解释器的选项字典。

如果script是字符“-”，并且不是最后一个handler，则会调用下一个handler的脚本。handler按顺序匹配，并且只选中第一个匹配的handler。要注意的是on error等价于trap {}会覆盖后续的任何trap。

如果在handler或finally执行时出现异常，原始异常的状态字典将添加到新的异常状态字典的-during键下。

proc testTry {num} {
	try {
		return [expr 1/$num]
	} on error {code options} {
		puts $code
		puts $options
	} on return {res options} {
		puts $res
		puts $options
	} finally {
		puts "finally"
	}
	
}
testTry 0
testTry 1

proc testTryTrap {} {
	try {
		 expr 1/0
	} trap {POSIX } {code options} {
		puts "POSIX"
	} trap {ARITH} {code options} {
		puts $code
		puts $options
	} finally {
		puts "finally"
	}
}
testTryTrap

throw

throw type message

Tcl8.6新增，此命令将抛出异常，并终止执行。创建的错误由类型type和消息message描述。type必须包含以机器可读的形式描述错误的单词列表，将成为结果字典的错误代码部分。message为人类可读形式的文本。堆栈将被解除，直到错误被合适的catch或try命令捕获为止。如果达到事件循环一直没有被捕获，则会通过bgerror机制进行报告。如果达到tclsh脚本执行的最高级别，将会在控制台打印，在非交互的情况下，将导致退出。通常type参数一般是从一般到具体，以除以0为例：

throw {ARITH DIVZERO {divide by zero}} {divide by zero}

type从ARITH到DIVZERO到divide by zero就是从一般到具体的说明。